德国赫优讯自动化有限公司 浙江华通信息技术有限公司提供完整Zigbee解决方案    

[硬件] ARM启动代码

[ 486 查看 / 0 回复 ]

返回列表
发新话题 回复该主题
qiaoni
头像

  • 助理工程师
  • 3
  • 48
  • 2009-10-12
2009-10-12 06:02 |只看楼主 1#
t T
学ARM已经41天了，中间断断续续总有点收获，今天把我写的启动代码贴上来，注释很详细，希望对咱们刚学的有帮助吧。

启动代码是几乎是每个arm程序程序必备的，刚开始看的时候看别人的启动代码时感觉云里雾里，所以懒惰的想法浮现脑中：别人都写好了我还写什么，直接拿来用不就行了，对在我懂得情况下，我一定会拿来就用，但是现在我还不懂，一切就要从头开始，经过几天的努力，现在的感觉是启动代码不过如此 ,呵呵。
  1. ;---------------------------------------------------------------------
  2. ;startup.s
  3. ;系统启动代码
  4. ;起始时间 : 2009.5.7 ----->2009.5.11
  5. ;---------------------------------------------------------------------



  9. ;---------------------------------------------------------------------
  10. GET ./Include/s3c2440.inc ;寄存器地址信息
  11. GET ./Include/memcfg.inc ;内存控制器配置信息

  13. ;处理器模式
  14. USERMODE EQU  0x10
  15. FIQMODE EQU  0x11
  16. IRQMODE EQU  0x12
  17. SVCMODE EQU  0x13
  18. ABORTMODE EQU  0x17
  19. UNDEFMODE EQU  0x1b
  20. SYSMODE EQU 0x1f
  21. ;相关掩码
  22. MODEMASK    EQU  0x1f
  23. NOINT EQU  0xc0

  25. ;各个处理器模式下堆栈设置
  26. _STACK_BASEADDRESS EQU 0x33ff8000 ;BANK6 64MB顶部
  27. UserStack EQU (_STACK_BASEADDRESS-0x3800) ;0x33ff4800 ~
  28. SVCStack EQU (_STACK_BASEADDRESS-0x2800) ;0x33ff5800 ~
  29. UndefStack EQU (_STACK_BASEADDRESS-0x2400) ;0x33ff5c00 ~
  30. AbortStack EQU (_STACK_BASEADDRESS-0x2000) ;0x33ff6000 ~
  31. IRQStack EQU (_STACK_BASEADDRESS-0x1000) ;0x33ff7000 ~
  32. FIQStack EQU (_STACK_BASEADDRESS-0x0) ;0x33ff8000 ~

  34. ;导入操作系统入口函数
  35. IMPORT OSEntry

  37. ;导入外部C语言编写的异常与中断处理函数
  38. IMPORT vectorUNDEF
  39. IMPORT vectorSWI
  40. IMPORT vectorPABT
  41. IMPORT vectorDABT
  42. IMPORT vectorIRQ
  43. IMPORT vectorFIQ

  45. ;导入镜像装载域段起始地址
  46. IMPORT  |Image$$RO$$Limit|  ; End of ROM code (=start of ROM data)
  47. IMPORT  |Image$$RW$$Base|  ; Base of RAM to initialise
  48. IMPORT  |Image$$ZI$$Base|  ; Base and limit of area
  49. IMPORT  |Image$$ZI$$Limit|  ; to zero initialise
  50. ;--------------------------------------------------------------------


  53. ;------------------------------------------------------
  54. AREA startup, CODE, READONLY

  56. ENTRY

  58. ;系统向量表

  60. b vectorRESET ;复位向量
  61. b vectorUNDEF ;未定义指令
  62. b vectorSWI ;软中断
  63. b vectorPABT ;预取指终止
  64. b vectorDABT ;数据终止
  65. b . ;系统保留
  66. b vectorIRQ ;外部中断
  67. b vectorFIQ ;快速中断
  68. ;-------------------------------------------------------

  70. ;--------------------------------------------------------------------------
  71. ;复位向量
  72. ;复位向量是ARM处理器上电后第一个被执行的异常
  73. ;此时系统处理管理(SVC)模式

  75. vectorRESET

  77. ;复位向量有以下六件事要做

  79. ;第一步 : 关闭看门狗定时器屏蔽所有中断
  80. ;第二步 : 配置系统时钟
  81. ;第三步 : 配置内存控制器
  82. ;第四步 : 配置每种处理器模式下堆栈指针
  83. ;第五步 : 初始化镜像运行域
  84. ;第六步 : 跳转到操作系统入口


  87. ;------------------------------------------
  88. ;第一步 : 关闭看门狗定时器
  89. ;具体内容请参看s3c2440a数据手册的第18章
  90. ldr r0, =WTCON
  91. ldr  r1, =0x0
  92. str  r1, [r0, #0x0]

  94. ;屏蔽所有中断
  95. ldr r0, =INTMSK
  96. ldr r1, =0xffffffff
  97. str r1, [r0]
  98. ;------------------------------------------



  102. ;------------------------------------------
  103. ;第二步 : 配置系统时钟
  104. ;具体内容请看手册第7章

  106. ;先减少锁相环锁定时间，s3c2440a要求PLL
  107. ;锁定时间>300us,在上电时s3c2440a预设值
  108. ;mpll为晶体频率，我用的晶体频率为12MHz
  109. ;300us*12M = 3600设置LOCKTIME = 0xfff
  110. ;足够了
  111. ldr r0, =LOCKTIME
  112. ldr r1, =0xfff0fff0 ;高16为对应UPLL
  113. ;低16为对应MPLL
  114. str r1, [r0, #0x0]

  116. ;根据器件手册我们还有以下几个事要做
  117. ;step1.配置UPLL
  118. ;step2.配置MPLL
  119. ;注:手册要求先配置UPLL后MPLL
  120. ; 且之间要间隔7NOP
  121. ; 详请看手册第7-21.
  122. ;step3.配置分频系数

  124. ;step1:
  125. ldr r0, =UPLLCON
  126. ldr r1, =((56<<12) + (2<<4) + 2)
  127. ldr r1, [r0]

  129. ;按手册要求插入7个NOP
  130. nop
  131. nop
  132. nop
  133. nop
  134. nop
  135. nop
  136. nop

  138. ;step2:
  139. ldr r0, =MPLLCON
  140. ldr r1, =((127<<12) + (2<<4) + 1)
  141. ldr r1, [r0]

  143. ;step3:
  144. ldr r0, =CLKDIVN
  145. ldr r1, =((0<<3) + (2 << 2) + 1)
  146. ldr r1, [r0]
  147. ;------------------------------------------



  151. ;------------------------------------------
  152. ;第三步 : 配置内存控制器
  153. ;内存控制内的寄存器器地址是连续分布的
  154. ;从0x4800_0000 -- 0x4800_0030,所以可以
  155. ;通过一个循环依次填入各个寄存器的内容

  157. ldr r0, =SMRDATA ;装入配置值的地址
  158. ldr r1, =BWSCON ;装入起始寄存器地址
  159. add r2, r0, #0x34 ;计算结束地址

  161. ;下面是用于向内存控制器
  162. ;装入配置信息的循环
  163. 0
  164. ldr r3, [r0], #4 ;装入配置值到r3,后变址
  165. str r3, [r1], #4  ;把r3内包含的配置值写入
  166. ;内存控制器的寄存器
  167. cmp r2, r0 ;结束否?
  168. bne %B0 ;没结束则继续
  169. ;------------------------------------------



  173. ;------------------------------------------
  174. ;第四步 : 配置每种处理器模式下堆栈指针
  175. ;方法与原则:
  176. ;1: 通过CPSR寄存器切换处理器模式
  177. ;2: 对CPSR的操作方式为 读-修改-写回
  178. ;3: 绝对不要跳到用户模式,跳过去容易
  179. ; 回来就难了
  180. ;4: 切到新处理器模式后要屏蔽IRQ和FIQ
  181. ; 防止在未设置好堆栈前进入中断处理
  182. ; 程序，但是在启动代码的最先我们已
  183. ; 经屏蔽了所有的32个中断源，所以感
  184. ; 觉是否屏蔽都可以

  186. ;step1: 先把程序状态寄存器读到r0
  187. mrs r0, cpsr

  189. ;step2: 清除处理器模式位(最前面5位)
  190. bic r0, r0, #MODEMASK

  192. ;step3: 设置未定义状态下的堆栈指针
  193. orr r1, r0, #UNDEFMODE|NOINT
  194. msr cpsr_cxsf, r1 ;UndefMode
  195. ldr sp, =UndefStack ;UndefStack=0x33FF_5C00

  197. ;step4: 设置终止状态下的堆栈指针
  198. orr r1, r0, #ABORTMODE|NOINT
  199. msr cpsr_cxsf, r1 ;AbortMode
  200. ldr sp, =AbortStack ;AbortStack=0x33FF_6000

  202. ;step5: 设置中断模式下的堆栈指针
  203. orr r1, r0, #IRQMODE|NOINT
  204. msr cpsr_cxsf, r1 ;IRQMode
  205. ldr sp, =IRQStack ;IRQStack=0x33FF_7000

  207. ;step6: 设置快速中断模式下的堆栈指针
  208. orr r1, r0, #FIQMODE|NOINT
  209. msr cpsr_cxsf, r1 ;FIQMode
  210. ldr sp, =FIQStack ;FIQStack=0x33FF_8000

  212. ;step7: 设置管理模式下的堆栈指针
  213. orr r1, r0, #SVCMODE|NOINT
  214. msr cpsr_cxsf, r1 ;SVCMode
  215. ldr sp, =SVCStack ;SVCStack=0x33FF_5800

  217. ;step8: 因为管理模式与用户模式共用
  218. ; 堆栈指针,所以借着系统模式
  219. ; 来设置用户模式的堆栈指针
  220. orr r1, r0, #SYSMODE|NOINT
  221. msr cpsr_cxsf, r1 ;SYSMode
  222. ldr sp, =UserStack ;SVCStack & USERMode=0x33ff4800

  224. ;现在处理器处于系统模式
  225. ;------------------------------------------
  226.    
  227.    
  228.    
  229. ;------------------------------------------
  230. ;第五步 : 初始化镜像运行域
  231. ;复制RW段和ZI段到SDRAM指定地址

  233. LDR    r0, =|Image$$RO$$Limit| ; 装入RO段结束地址
  234. LDR    r1, =|Image$$RW$$Base|  ; 装入RW段起始地址
  235. LDR    r3, =|Image$$ZI$$Base|  ; 装入ZI段起始地址


  238. ;|Image$$RO$$Limit| == |Image$$RW$$Base| ? 跳过RW段复制 : 复制RW段
  239. CMP    r0, r1     
  240. BEQ    %F2

  242. ;复制RW段
  243. 1       
  244. CMP    r1, r3 
  245. LDRCC  r2, [r0], #4     
  246. STRCC  r2, [r1], #4
  247. BCC    %B1
  248. 2       
  249. LDR    r1, =|Image$$ZI$$Limit| 
  250. MOV    r2, #0

  252. ;构造ZI段
  253. 3       
  254. CMP    r3, r1     
  255. STRCC  r2, [r3], #4
  256. BCC    %B3

  258. ;------------------------------------------   



  262. ;------------------------------------------
  263. ;第六步 : 跳转到操作系统入口

  265. b OSEntry ;不要使用main，因为如果使用main
  266. ;ads还会调用_main()初始化RW和ZI
  267. ;段,但是那里的数据和本程序不同

  269. b .

  271. ;------------------------------------------

  273. ;---------------------------------------------------------------------------



  277. SMRDATA DATA

  279. ;这里是内存控制器的配置数据
  280. ;配置数据需要根据你使用的存储器修改
  281. ;在第三步时会将以下数据写入
  282. ;内存控制器的相关寄存器中
  283. ;共13个寄存器的配置值

  285. DCD (0+(B1_BWSCON<<4)+(B2_BWSCON<<8)+(B3_BWSCON<<12)+(B4_BWSCON<<16)+(B5_BWSCON<<20)+(B6_BWSCON<<24)+(B7_BWSCON<<28))
  286. DCD ((B0_Tacs<<13)+(B0_Tcos<<11)+(B0_Tacc<<8)+(B0_Tcoh<<6)+(B0_Tah<<4)+(B0_Tacp<<2)+(B0_PMC))  ;GCS0
  287. DCD ((B1_Tacs<<13)+(B1_Tcos<<11)+(B1_Tacc<<8)+(B1_Tcoh<<6)+(B1_Tah<<4)+(B1_Tacp<<2)+(B1_PMC))  ;GCS1
  288. DCD ((B2_Tacs<<13)+(B2_Tcos<<11)+(B2_Tacc<<8)+(B2_Tcoh<<6)+(B2_Tah<<4)+(B2_Tacp<<2)+(B2_PMC))  ;GCS2
  289. DCD ((B3_Tacs<<13)+(B3_Tcos<<11)+(B3_Tacc<<8)+(B3_Tcoh<<6)+(B3_Tah<<4)+(B3_Tacp<<2)+(B3_PMC))  ;GCS3
  290. DCD ((B4_Tacs<<13)+(B4_Tcos<<11)+(B4_Tacc<<8)+(B4_Tcoh<<6)+(B4_Tah<<4)+(B4_Tacp<<2)+(B4_PMC))  ;GCS4
  291. DCD ((B5_Tacs<<13)+(B5_Tcos<<11)+(B5_Tacc<<8)+(B5_Tcoh<<6)+(B5_Tah<<4)+(B5_Tacp<<2)+(B5_PMC))  ;GCS5
  292. DCD ((B6_MT<<15)+(B6_Trcd<<2)+(B6_SCAN))    ;GCS6
  293. DCD ((B7_MT<<15)+(B7_Trcd<<2)+(B7_SCAN))    ;GCS7
  294. DCD ((REFEN<<23)+(TREFMD<<22)+(Trp<<20)+(Trc<<18)+(Tchr<<16)+REFCNT)
  295. DCD 0x32    ;SCLK power saving mode, BANKSIZE 128M/128M
  296. DCD 0x30    ;MRSR6 CL=3clk
  297. DCD 0x30    ;MRSR7 CL=3clk

  299. ALIGN ;数据边界对齐

  301. END
复制代码
我在写一个arm920T的微型OS，主要是想借着写OS的过程学习ARM的底层编程，然后跳到Linux。启动代码是固件的一部分，最经学校要搞个设计，不知OS什么时候能写好，反正搞定后立即发帖。

下边是完整的工程

运行平台：mini2440
最后编辑qiaoni 最后编辑于 2009-10-12 06:04:22
附件:您所在的用户组无法下载或查看附件
分享 转发
TOP
返回列表
上一主题 | 下一主题